Турбо-Паскаль 7.0

WriteLn (y)

END.

Пояснение: В программе 5 операторов, последний - WriteLn (y). Поскольку эти 5 операторов выполняются по порядку, то он выполнится обязательно.

Задача 2. В компьютер вводятся два произвольных положительных числа - длины сторон двух кубиков. Компьютер должен подсчитать объем одного кубика - большего по размеру .

Обозначим a1 - сторону одного кубика, a2 - сторону другого, bol - сторону большего кубика, V - объем кубика. Приведем три варианта программы:

ВАРИАНТ 1	VAR a1,a2 : Real; BEGIN ReadLn (a1,a2); if a1>a2 then WriteLn (a1*a1*a1 : 15:5) else WriteLn (a2*a2*a2 : 15:5) END.
ВАРИАНТ 2	VAR a1,a2,V : Real; BEGIN ReadLn (a1,a2); if a1>a2 then V:=a1*a1*a1 else V:=a2*a2*a2; WriteLn (V : 15:5) END.
ВАРИАНТ 3	VAR a1,a2,bol,V : Real; BEGIN ReadLn (a1,a2); if a1>a2 then bol:=a1 else bol:=a2; V:=bol*bol*bol; WriteLn (V : 15:5) END.

Поясним последний вариант. Программа состоит из четырех операторов, которые выполняются в порядке записи. Первым после запуска выполняется оператор ReadLn (a1,a2), который ждет от нас ввода двух чисел. Пусть мы сегодня ввели числа 3 и 2. Компьютер понимает, что a1 равно 3, a2 равно 2, и переходит к выполнению оператора if. Он видит, что 3>2, и поэтому выполняет оператор bol:=a1, а оператор bol:=a2 не выполняет. В результате в ячейке bol оказывается число 3. Затем компьютер переходит к следующему оператору - V:=bol*bol*bol и вычисляет V=3*3*3=27. Следующий оператор WriteLn (V : 15:5) печатает число 27.00000 .

Если завтра мы запустим эту же программу и введем числа 6 и 10, то компьютер увидит, что утверждение 6>10 ложно, и поэтому выполнит оператор bol:=a2, а оператор bol:=a1 выполнять не станет. В результате в ячейке bol окажется число 10 и будет напечатано число 1000.00000 .

А теперь, дорогой читатель, вам пришла пора освоить пошаговый режим выполнения программы на компьютере. В обычном режиме компьютер выполняет программу настолько быстро, что вы не успеваете заметить, в каком порядке он выполняет отдельные операторы программы, а без этого часто невозможно понять ее логику. Пошаговый режим заставляет компьютер при выполнении программы задерживаться на каждой строке программы столько, сколько нужно человеку. Сейчас вам необходимо проделать то, что сказано в части IV в пункте «Пошаговый режим» параграфа «Исправление ошибок. Отладка программы».

Итак, если паровая машина избавила человека от тяжелого физического труда, то оператор if избавил человека от тяжелого умственного труда, в нашем случае - от необходимости решать, какое из двух чисел больше другого.

Оператор if можно записывать и без части else. Например, if s<t then w:=a+1. Это означает, что если s<t, то нужно выполнить оператор w:=a+1, в противном случае ничего не делать, а просто перейти к следующему оператору.

Для примера рассмотрим простейшую задачу: В компьютер вводится слово. Компьютер должен просто распечатать его. Однако, если введенным словом будет "колхозник", то компьютер должен напечатать вместо него слово "фермер".

Вот как будет выглядеть наша программа-"цензор":

VAR Slovo : String;

BEGIN

ReadLn (Slovo); { переменная Slovo будет иметь значением строку символов, введенных с клавиатуры }

if Slovo = 'колхозник' then Slovo := 'фермер';

WriteLn (Slovo)

END.

2.2.2 Правила записи оператора IF

У каждого человеческого языка есть своя грамматика, включающая в себя правила, по которым должны выстраиваться в цепочку элементы языка, чтобы получилось правильное предложение. Совокупность этих правил образует часть грамматики, называемую синтаксисом. В языках программирования тоже есть предложения. Такими предложениями здесь являются операторы. Следовательно, у языков программирования тоже должен быть свой синтаксис, который описывает правила, по которым записываются операторы языка и из операторов составляется программа. После того, как человек запускает программу на выполнение, любая порядочная среда программирования прежде, чем действительно выполнять ее, сначала проверит, нет ли в ней синтаксических ошибок, и если есть, то программу выполнять не будет, а выдаст сообщение, указывающее человеку, в чем ошибка.

Пока мы не готовы воспринять полный синтаксис оператора if Паскаля (вы найдете его в 14.8), однако уже сейчас нам хотелось бы писать без ошибок. Для этого, скрепя сердце, будем использовать сокращенный синтаксис. Поясним его в виде синтаксической схемы:

IF условие THEN оператор ELSE оператор

Как понимать эту схему? Ее следует понимать, как образец, шаблон записи оператора, указывающий порядок, в котором оператор записывается из отдельных слов. Слова, которые в схеме я записал жирными заглавными буквами, при записи оператора просто копируются. Вместо слов, которые в схеме записаны строчными буквами, нужно при записи оператора подставить то, что они означают. Поясним, что обозначают эти слова.

оператор	любой оператор Паскаля
условие	пока под условием будем понимать два арифметических выражения, соединенных знаком сравнения, или условие равенства или неравенства строк, как это показано на примере в 5.1
выражение	что такое выражение, было пояснено в 4.9
знак сравнения	знаков сравнения шесть: > больше >= больше или равно = равно < меньше <= меньше или равно <> не равно

Пример: if 5*a+4 <= a*b then WriteLn (b) else a:=b+5

Здесь

WriteLn (b) - один оператор,

a:=b+5 - другой оператор,

5*a+4 <= a*b - условие,

5*a+4 - одно выражение,

a*b - другое выражение,

<= - знак сравнения.

Вспомним правило расстановки точек с запятыми. Они применяются для того, чтобы отделять друг от друга операторы, выполняющиеся друг за другом. Поэтому и после оператора if мы тоже ставили точку с запятой, если после него шел какой-нибудь оператор. Распространенная привычка начинающих программистов - автоматически ставить точку с запятой после любого оператора, независимо от того, что после него стоит - другой оператор или же служебное слово, например else или end. Так вот, перед end точку с запятой ставить не возбраняется, а

перед ELSE точку с запятой ставить запрещено.

В п.5.1 вы уже видели, что оператор if можно записывать в краткой форме:

IF условие THEN оператор

Таким образом, это уже вторая синтаксическая схема, касающаяся одного оператора. Удобно же весь синтаксис оператора иметь перед глазами в одной схеме. Соединим две схемы в одну. Вот эта схема:

IF условие THEN оператор [ ELSE оператор ]

Квадратные скобки здесь означают, что их содержимое можно писать, а можно и не писать в операторе.

Полезное замечание: Вычисляя выражения, стоящие в условии оператора if, Паскаль не записывает их значения в память. Например, после выполнения фрагмента - b:=6; if b+1>0 then s:=20 - в ячейке b будет храниться 6, а не 7. То же относится и к выражениям из оператора WriteLn. Например: b:=6; WriteLn (b+1) . И здесь тоже в ячейке b останется храниться 6, а не 7. И вообще, информация в ячейках памяти не меняется при вычислении выражений.

Примеры работы оператора if:

ФРАГМЕНТ ПРОГРАММЫ	ЧТО НА ЭКРАНЕ
a:=10; if a>2 then WriteLn ('!!!') else WriteLn ('!')	!!!
a:=4; if a>5 then a:=a+10 else a:=a-1; WriteLn (a)	3
s:=6; if s-8<0 then s:=s+10; WriteLn (s)	16
s:=6; if s<0 then s:=s+10; s:=s+1; WriteLn (s)	7

Пояснение: Обратите внимание, что в последнем примере оператор if кончается оператором s:=s+10, а не s:=s+1. Поэтому оператор s:=s+1 будет выполняться всегда, независимо от величины s.

Задания 18-20:

Определить без компьютера, что будет напечатано при выполнении следующих фрагментов программ:

18. k:=20; k:=k+10; if k+10<>30 then k:=8 else k:=k-1; WriteLn (k)

19. k:=20; k:=k+10; if k+10 = 30 then k:=8 else k:=k-1; WriteLn (k)

20. p:=1; if p>0 then p:=p+5; Write (p); if p>10 then p:=p+1; Write (p)

Задания 21-23:

21. В компьютер вводятся два числа. Если первое больше второго, то вычислить их сумму, иначе - произведение. После этого компьютер должен напечатать текст ЗАДАЧА РЕШЕНА.

22. В компьютер вводятся длины трех отрезков. Компьютер должен ответить на вопрос, правда ли, что первый отрезок не слишком длинен, чтобы образовать с другими двумя отрезками треугольник.

Указание: Для этого его длина должна быть меньше суммы длин двух других отрезков. Замечание: Пока не думайте о том, что слишком длинными могут быть второй или третий отрезки. Об этом - задание из 5.5.

23. Дракон каждый год отращивает по три головы, но после того, как ему исполнится 100 лет - только по две. Сколько голов и глаз у дракона, которому N лет?

2.2.3 Составной оператор

Вот фрагмент программы, которая складывает два числа:

WriteLn ('Введите два числа');

ReadLn (a,b);

WriteLn ('Сумма равна ' ,a+b)

Вот фрагмент программы, которая возводит число в квадрат:

WriteLn ('Введите число');

ReadLn (a);

WriteLn ('Квадрат числа равен ' ,a*a)

Пусть мы хотим сделать программу, которая бы по желанию пользователя или складывала два числа, или возводила одно число в квадрат, то есть выполняла или первый или второй фрагмент.

Начинаться наша программа могла бы примерно так:

VAR Otvet : String; . . . . .

BEGIN

WriteLn ('Чем займемся - сложением или возведением в квадрат?');

ReadLn (Otvet);

if Otvet = 'сложением' then . . . . else . . . .

Здесь после then мы должны бы вставить первый фрагмент, а после else второй. Однако, тут возникает проблема. Каждый из фрагментов состоит из нескольких операторов, а синтаксис оператора if разрешает ставить после then и else только по одному оператору. Чтобы преодолеть эту трудность, в Паскале есть средство превратить последовательность записанных друг за другом операторов формально в один оператор. Для этого последовательность заключается между словами begin и end и получившаяся конструкция называется составным оператором.

Вот первый фрагмент в виде составного оператора:

begin

WriteLn ('Введите два числа');

ReadLn (a,b);

WriteLn ('Сумма равна ' ,a+b)

end

Компьютер выполняет составной оператор неотличимо от последовательности операторов, из которых он состоит, однако титул составного оператора позволяет ему считаться одним оператором и поэтому быть вхожим в те места программы, в которые разрешен вход только единичным операторам, а не их последовательностям, как, например, имеет место в нашем случае с оператором if.

Вот какая получится программа для нашей задачи:

VAR Otvet :String;

a,b :Integer;

BEGIN

WriteLn ('Чем займемся - сложением или возведением в квадрат?');

ReadLn (Otvet);

if Otvet = 'сложением'

then

begin WriteLn ('Введите два числа');

ReadLn (a,b);

WriteLn ('Сумма равна ' ,a+b)

end

else

begin WriteLn ('Введите число');

ReadLn (a);

WriteLn ('Квадрат числа равен ' ,a*a)

end;

WriteLn ('Счет завершен')

END.

У нашей программы есть недостаток. Если при ответе на вопрос компьютера мы чуть-чуть ошибемся, например, ответим не "сложением", а "сложение", компьютер будет выполнять возведение в квадрат, так как в условии оператора if сравниваемые строки должны совпадать полностью. Научившись выполнять операции над строками, вы научитесь избегать таких ситуаций.

Задание 24: Видоизменить диалог с компьютером, начатый в 4.15. Пусть компьютер, узнав возраст человека, дальнейшую беседу ведет по двум вариантам. Если возраст больше 17, то компьютер должен задать вопрос: "В каком институте ты учишься?" и получив ответ, глубокомысленно заметить "Хороший институт". Если же возраст меньше или равен 17, то соответственно - "В какой школе ты учишься?" и "Неплохая школа". После этого, каков бы ни был вариант, компьютер должен попрощаться: "До следующей встречи!".

2.2.4 Ступенчатая запись программы

Обратите внимание на то, на что не обращает внимания компьютер, а именно на отступы от левого края листа в записи строк программы из 5.3. Строки VAR, BEGIN и END записаны без отступа. Между словами BEGIN и END записаны четыре оператора: WriteLn, ReadLn, if и WriteLn. Все они выполняются по порядку, один за другим, поэтому каждый из них записан с одинаковым отступом. Если оператор сложный, то есть включает в себя другие операторы (мы знаем пока два таких оператора - if и составной), то составляющие его операторы записываются еще правее. Слова, составляющие пару (then и else, begin и end) записываются друг под другом.

Сделано все это для удобства чтения программы, для того, чтобы глаз мог сразу же уловить структуру программы, а именно, из каких частей состоит как сама программа, так и каждый из элементов, ее составляющих. Впрочем, вам с первого взгляда может показаться, что такая запись, наоборот, неудобна для чтения. Однако, заметьте, что ступенчатая запись принята во всем мире и глаза профессиональных программистов привыкли именно к ней. Настолько привыкли, что программа, записанная без соблюдения ступенчатого стиля, вызывает раздражение.

Конечно, допустимы и некоторые отклонения от ступенчатого стиля. Например, несколько коротких похожих операторов вполне можно записать в одну строку:

a:=0; b:=0; c:=0; f:=4;

Этим мы экономим дефицитное место по вертикали экрана или листа бумаги.

2.2.5 Вложенные операторы if. Сложное условие в операторе if. Логические операции

Согласно синтаксической схеме оператора if, после then и else может стоять любой оператор Паскаля, в том числе и if.

Решим задачу: В компьютер вводится число (пусть для конкретности это будет дальность какого-нибудь выстрела). Если оно находится в интервале от 28 до 30, то напечатать текст ПОПАЛ, иначе - НЕ ПОПАЛ.

Сначала составим алгоритм: Введи число. Если оно больше 28, то надо еще подумать, в противном случае печатай НЕ ПОПАЛ. А о чем же думать? А вот о чем: Если число меньше 30, то печатай ПОПАЛ, иначе печатай НЕ ПОПАЛ.

А теперь по составленному алгоритму напишем программу:

VAR a : Real;

BEGIN

ReadLn (a);

if a>28 then if a<30 then WriteLn ('ПОПАЛ')

else WriteLn ('НЕ ПОПАЛ')

else WriteLn ('НЕ ПОПАЛ')

END.

Как компьютер не запутается в этих then и else? Если внимательно присмотреться, то можно увидеть, что двусмысленная ситуация получается только тогда, когда один из if записан без else, а другой - с else. Пример:

d:=3; v:=10; if v<6 then if v<20 then d:=1 else d:=2

Чему будет равняться d после выполнения этого фрагмента - 1, 2 или 3? Ответ зависит от того, какому if принадлежит else - if v<6 или if v<20 ? Чтобы ответить на этот вопрос, пойдем по тексту программы от интересующего нас else к началу и если по пути нам не встретится еще один else. то первый же if, на который мы наткнемся - наш. Если по пути нам встретится еще один else, забудем пока про наш else и найдем сначала if для нового else, а со старым разберемся потом.

Испытайте-ка этот способ в нашем фрагменте и в предыдущей программе. Получается, что else в нашем примере принадлежит if v<20 и значит, d будет равняться 3.

Задание 25: Усложним задание из 5.2: В компьютер вводятся длины трех отрезков. Компьютер должен ответить на вопрос, правда ли, что эти отрезки могут образовать треугольник.

Указание: Для этого каждый отрезок должен быть меньше суммы длин двух других отрезков.

На первый взгляд применение if внутри if создает громоздкую, трудную для понимания программу. Однако, если вы будете аккуратно использовать ступенчатую запись, то программа получится достаточно обозримой.

В Паскале, тем не менее, есть возможность записывать многие программы со вложенными друг в друга if короче и понятнее, используя только один if. Для этого используются логические операции.

Задача "Разборчивая принцесса". В прихожей у принцессы - длинная очередь женихов. Принцессе нравятся только голубоглазые маленького роста. Устав принимать женихов и отбирать из них подходящих, принцесса вместо себя поставила компьютер, написав для него программу, которая говорит ВЫ МНЕ ПОДОЙДЕТЕ тем, у кого цвет глаз голубой и рост меньше 140 см. Остальным программа говорит ДО СВИДАНИЯ.

Вот эта программа:

VAR Tsvet :String; {Цвет}

Rost :Integer; {Рост}

BEGIN

WriteLn ('Каков цвет ваших глаз?');

ReadLn (Tsvet);

WriteLn ('Введите ваш рост в сантиметрах');

ReadLn (Rost);

if (Tsvet ='Голубой') AND (Rost<140) {Если цвет голубой И рост<140}

then WriteLn ('ВЫ МНЕ ПОДОЙДЕТЕ')

else WriteLn ('ДО СВИДАНИЯ')

END.

Мы видим, что условие в операторе if уже не такое простое, как мы описывали раньше, а сложное, то есть состоящее из двух взятых в скобки условий В скобки условия нужно брать потому, что «приоритет» операции AND выше, чем у операций сравнения «=» и «<», то есть она выполняется раньше них, точно так же, как, скажем, умножение выполняется раньше сложения. В Паскале все арифметические, логические и другие операции объединены в единую систему приоритетов. Рассмотрение этой системы выходит за рамки книги., соединенных знаком логической операции AND (читается "энд", переводится "и"). Весь оператор if можно прочесть так - если цвет глаз голубой И рост меньше 140 сантиметров, то печатай ВЫ МНЕ ПОДОЙДЕТЕ, иначе печатай ДО СВИДАНИЯ.

Знак логической операции AND, поставленный между двумя условиями, говорит о том, что должны выполняться сразу оба эти условия.

Поэтому наш оператор if ответит ДО СВИДАНИЯ и высоким голубоглазым и высоким неголубоглазым и маленьким неголубоглазым. И лишь маленьким голубоглазым он ответит ВЫ МНЕ ПОДОЙДЕТЕ.

Программа для задачи ПОПАЛ - НЕ ПОПАЛ при использовании логических операций значительно упростится:

VAR a :Real;

BEGIN

ReadLn (a);

if (a>28) AND (a<30) then WriteLn ('ПОПАЛ')

else WriteLn ('НЕ ПОПАЛ')

END.

Задача "Неразборчивая принцесса". Неразборчивой принцессе нравятся все маленькие независимо от цвета глаз и все голубоглазые независимо от роста. Программа неразборчивой принцессы будет отличаться от программы разборчивой одним единственным знаком логической операции:

if (Tsvet ='Голубой') OR (Rost<140) {Если цвет голубой ИЛИ рост<140}

Знак логической операции OR читается "о", переводится "или".

Поставленный между двумя условиями, знак OR говорит о том, что достаточно, если будет выполняться хотя бы одно из них.

Поэтому теперь оператор if ответит ВЫ МНЕ ПОДОЙДЕТЕ и высоким голубоглазым и маленьким голубоглазым и маленьким неголубоглазым. И лишь высоким неголубоглазым он ответит ДО СВИДАНИЯ.

Знаками AND и OR можно объединять сколько угодно условий. Например:

if (a>2) OR (x=b) OR (c<>1) then k:=99 else k:=33

Здесь выполнится оператор k:=99, если верно хотя бы одно из трех условий, и лишь когда все три неверны, будет выполняться оператор k:=33.

Кроме логических операций AND и OR применяется еще логическая операция NOT (читается "нот", переводится "не"). Запись if NOT(a>b) then... переводится так - ЕСЛИ НЕПРАВДА, ЧТО a больше b, ТО.... Вот фрагмент:

a:=2; b:=3; if NOT(a>b) then k:=1 else k:=0

Здесь выполнится оператор k:=1, так как неправда, что 2>3.

Для простоты примем правило, что условия, к которым применяются логические операции, заключаются в круглые скобки, хотя это не всегда обязательно.

Внутри скобок можно писать не только простые, но и сложные условия. Например, фрагмент if NOT ((a>2) AND (b>3)) AND (s>8)) then... можно перевести так - если неправда, что одновременно верны три условия - a>2, b>3, s>8, то...

Примеры:

ФРАГМЕНТ	РЕЗУЛЬТАТ
a:=8; b:=6; if (a>b) AND (b>7) then k:=1 else k:=0	k=0
a:=8; b:=6; if (a>b) OR (b>7) then k:=1 else k:=0	k=1
a:=8; b:=6; if (a<b) OR (b>7) then k:=1 else k:=0	k=0
a:=8; b:=6; if NOT (a=8) then k:=1 else k:=0	k=0

Задание 26: "Замысловатая принцесса". Определите, кто нравится принцессе, по фрагменту из ее программы:

if (Tsvet ='Черный') AND ((Rost<180) OR (Rost>184))

then WriteLn ('ВЫ МНЕ ПОДОЙДЕТЕ')

else WriteLn ('ДО СВИДАНИЯ')

До сих пор мы применяли оператор if для выбора одной из двух возможностей. Покажем, как применять его для выбора одной из нескольких. Усложним нашу задачу про ПОПАЛ - НЕ ПОПАЛ:

Человек вводит в компьютер число. Если оно находится в интервале от 28 до 30, то нужно напечатать текст ПОПАЛ, если оно больше или равно 30 - то ПЕРЕЛЕТ, если оно находится на отрезке от 0 до 28, то НЕДОЛЕТ, если число меньше нуля - НЕ БЕЙ ПО СВОИМ.

Вот программа:

VAR a : Real;

BEGIN

ReadLn (a);

if (a>28) AND (a<30) then WriteLn ('ПОПАЛ');

if a>=30 then WriteLn ('ПЕРЕЛЕТ');

if (a>=0) AND (a<=28) then WriteLn ('НЕДОЛЕТ');

if a<0 then WriteLn ('НЕ БЕЙ ПО СВОИМ')

END.

Необходимо обращать внимание на аккуратную расстановку знаков сравнения и числовых границ диапазонов. Если во втором if вместо a>=30 мы напишем a>=20, то при вводе числа 25 компьютер даст нам двусмысленный ответ:

ПЕРЕЛЕТ

НЕДОЛЕТ

Если же мы вместо a>=30 напишем a>30, то при вводе числа 30 мы вообще не получим от компьютера никакого ответа.

Задание 27:

Человек вводит с клавиатуры строку, смысл которой - приветствие при встрече. Компьютер тоже должен ответить приветствием. Отвечать нужно в соответствии со следующей таблицей:

ПРИВЕТСТВИЕ ЧЕЛОВЕКА	ОТВЕТ КОМПЬЮТЕРА
Привет	Привет
Здравствуйте	Здравствуйте
Здорово	Здравствуйте
Добрый день	Салют
Приветик	Салют
Салют	Салют
Здравия желаю	Вольно

2.2.6 Символьный тип данных Char

Для того, чтобы получить более полное представление о возможностях оператора варианта case, который нам предстоит изучить, познакомимся сначала с новым типом данных. Мы с вами уже познакомились с четырьмя типами данных в Паскале: Integer и LongInt (целые числа), Real (вещественные числа) и String (строки символов). Введем еще один тип - Char (символьный). По-английски Char читается - "кэр", это сокращение от Character - "символ".

Описание VAR a,b: Char означает, что переменные a и b имеют право принимать значения любых символов, с которыми может работать компьютер. (О символах мы говорили в 3.5) Мы можем записать a:='Л'; b:='+', что означает приказ присвоить переменной a значение символа Л, а переменной b - значение символа +. Мы можем записать ReadLn (a) , что означает приказ компьютеру ждать ввода с клавиатуры любого одного символа и присвоить его значение переменной a. Мы можем записать WriteLn (b) и на экране появится плюсик.

Вот программа, переворачивающая любое трехбуквенное слово, введенное человеком с клавиатуры:

VAR c1,c2,c3: Char;

BEGIN

ReadLn (c1,c2,c3);

WriteLn (c3,c2,c1)

END.

Если мы по оператору ReadLn введем символы ТОК, то оператор WriteLn напечатает КОТ. При вводе нескольких символов одним оператором ReadLn, все символы набираются на клавиатуре подряд, без пробелов, которыми мы привыкли разделять при вводе числовые данные. После ввода последнего символа нажимаем клавишу Enter. Таким образом, ввод трех символов одним оператором ReadLn не отличается от ввода одной трехсимвольной строки. Вообще, тип Char похож на тип String. Строка состоит из символов, да и сам символ - это как бы очень короткая строка длиной в один символ.

2.2.7 Оператор варианта case

В Паскале есть специальный оператор, который позволяет делать выбор одной из нескольких возможностей. Рассмотрим программу, спрашивающую у ученика его отметку по чистописанию и реагирующую на нее подходящим текстом:

VAR Otmetka: Integer;

begin

WriteLn ('Какую отметку ты получил по чистописанию?');

ReadLn (Otmetka);

CASE otmetka OF {Перевод: В СЛУЧАЕ ЕСЛИ отметка РАВНА...}

1,2 :WriteLn('Кошмар!');

3 :WriteLn('Неважно');

4 :WriteLn('Неплохо');

5 :WriteLn('Молодец!');

ELSE WriteLn('Таких отметок не бывает')

END {Конец оператора CASE}

end.

Основой программы является оператор варианта CASE (читается "кэйс", переводится "случай"). Предлог OF читается "эв". Весь оператор CASE нужно понимать так:

В СЛУЧАЕ ЕСЛИ отметка РАВНА

1 или 2 печатай 'Кошмар!'

3 печатай 'Неважно'

4 печатай 'Неплохо'

5 печатай 'Молодец!'

ИНАЧЕ печатай 'Таких отметок не бывает'

КОНЕЦ оператора case

В процессе исполнения оператора case компьютер сравнивает значение переменной Otmetka по очереди со всеми значениями, перечисленными перед двоеточиями. Наткнувшись на совпадающее значение, он выполняет оператор, стоящий после двоеточия. На этом исполнение оператора case завершается. Если же совпадающего значения так и не нашлось, то выполняется оператор, стоящий после слова else (в нашей программе он полезен на тот случай, если ученик болен манией величия и вводит число 6). После else может стоять и цепочка операторов, записанных через точку с запятой.

Если вы еще недостаточно хорошо поняли логику оператора case, то обратите внимание на то, что в нашей программе он работает так же, как следующий оператор if:

if (Otmetka=1) OR (Otmetka=2)

then WriteLn('Кошмар!')

else if Otmetka=3

then WriteLn('Неважно')

else if Otmetka=4

then WriteLn('Неплохо')

else if Otmetka=5

then WriteLn('Молодец!')

else WriteLn('Таких отметок не бывает')

У оператора case есть существенное ограничение - переменная, стоящая после слова case, должна быть так называемого порядкового типа. Подробно о порядковых типах мы поговорим в Глава 12, пока же мы знаем три типа, относящиеся к порядковым - это Integer, LongInt и Char. Порядковыми они называются потому, что все их возможные значения можно выстроить по порядку и перечислить с начала до конца: -32768, ....4,5,6,7,8... 32767 для Integer, .....'д','е','ж','з','и'.... для Char. Получается, что значения типов Real и String применять в операторе case нельзя, так как совершенно непонятно, как их перечислять по порядку.

Таким образом, задачу про ПОПАЛ-НЕ ПОПАЛ в принципе невозможно решить при помощи case. И этому две причины: 1)переменная имеет тип Real, 2)перед двоеточием в операторе case нельзя писать условия со знаками >, < и т.п.

Вот еще пример программы с оператором case:

VAR a,k : Integer;

begin

a:=3;

case a*a+1 of {В СЛУЧАЕ ЕСЛИ a*a+1 РАВНО...}

8,3,20 :k:=0;

7,10 :begin k:=1; WriteLn(k) end;

12 ..18 :k:=3

end {Конец оператора CASE}

end.

Эта программа напечатает 1. Здесь мы видим несколько новых для нас элементов:

Во-первых, после слова case стоит не переменная, а выражение, поэтому с перечисленными перед двоеточиями значениями будет сравниваться число 10, полученное как 3*3+1. Кстати, выражение тоже обязано быть порядкового типа (о том, что такое тип выражения, мы строго поговорим в 14.4, а сейчас скажем только, что это выражение, имеющее значения порядкового типа).

Во-вторых, один из операторов, стоящих после двоеточий, составной. Это begin k:=1; WriteLn(k) end

В-третьих - конструкция 12 ..18 . Она обозначает то же, что и 12,13,14,15,16,17,18. Она служит в нашем случае для сокращения записи и называется диапазоном.

В-четвертых, здесь отсутствует конструкция else. Это значит, что если бы в нашей программе мы вместо a:=3 написали a:=0, то оператор case, не найдя совпадения, не выбрал бы ни один из трех своих вариантов и, не найдя также else, завершил бы свою работу, так ничего и не сделав.

Задание 28:

Ученик вводит с клавиатуры букву русского алфавита. Компьютер должен сказать, какая это буква - гласная, согласная звонкая, согласная глухая или другая какая-нибудь (можно и НЕ ЗНАЮ).

Задание 29: «Калькулятор». Ученик вводит с клавиатуры число, символ арифметического действия (+, -, *, /) и еще одно число. Компьютер должен напечатать результат. Указание: Используйте три оператора ReadLn.

2.3 Циклические программы

2.3.1 Оператор перехода GOTO. Цикл. Метки

Цикл - главное средство заставить компьютер много раз сделать одно и то же или похожее. Первое представление о цикле я дал в 2.8. Посмотрим, как осуществить цикл на Паскале. Предположим, мы хотим, чтобы компьютер бесконечно повторял выполнение следующего фрагмента:

Write ('Это ');

Write ('тело ');

Write ('цикла');

Write (' ')

в результате чего на мониторе мы бы увидели:

Это тело цикла Это тело цикла Это тело цикла Это тело цикла . . . .

Большинство языков программирования (в том числе и Паскаль) устроены так, что операторы выполняются в том порядке, в котором они записаны. Это значит, что после оператора Write ('Это ') обязательно выполнится оператор Write ('тело '), а после него - Write ('цикла'), а после него - Write (' '). Все это хорошо. Но нам нужно, чтобы после выполнения оператора Write (' ') Паскаль нарушал этот свой принцип последовательного выполнения операторов и выполнял бы оператор Write ('Это '). Если мы этого добьемся, то дальше все пойдет само собой, так как после Write ('Это ') Паскаль автоматически выполнит Write ('тело ') и так далее до бесконечности.

Если бы операторы Паскаля можно было писать по-русски, то для достижения нашей цели было бы естественно воспользоваться такой конструкцией:

метка m1: Write ('Это ');

Write ('тело ');

Write ('цикла');

Write (' ');

иди к оператору, помеченному меткой m1

Здесь мы видим новый для нас "оператор" ИДИ, который выполняется после Write (' ') и единственная работа которого заключается в том, чтобы заставить компьютер перескочить к выполнению оператора Write ('Это '), помеченного меткой m1.

А вот как этот фрагмент выглядит реально на Паскале:

m1: Write ('Это ');

Write ('тело ');

Write ('цикла');

Write (' ');

GOTO m1

Здесь GOTO - оператор перехода, читается " 'гоуту", переводится "иди к", m1 - метка.

Метка - это произвольное имя или произвольное не слишком большое целое положительное число. Оператор GOTO можно писать в любых местах программы и метку можно ставить перед любым оператором ,заставляя компьютер таким образом перескакивать в программе откуда угодно куда угодно (правда, в сложных программах и внутри сложных операторов эта свобода перескакивания существенно ограничивается. Метка должна отделяться от оператора двоеточием.

Мы пока знаем, что переменная, встречающаяся в программе, должна быть описана выше BEGIN после слова VAR. Метки, встречающиеся в программе, тоже должны быть описаны выше BEGIN после слова LABEL (читается "лэйбл", переводится "метка").

Вот наша программа полностью:

LABEL m1;

BEGIN

m1: Write ('Это ');

Write ('тело ');

Write ('цикла');

Write (' ');

goto m1

END.

Если вы уже запустили эту программу, то через некоторое время перед вами должен встать жизненно важный вопрос - как же ее остановить? Для этого достаточно прочесть параграф «Выполнение программы» из части IV. Вот вкратце, что вам нужно оттуда знать:

Для прерывания работы программы (в том числе и зациклившейся) существует комбинация клавиш Ctrl-Break (имеется в виду, что, удерживая нажатой клавишу Ctrl, вы должны щелкнуть по клавише Break). На экран возвращается окно редактора. Строка программы, на которой она была прервана, выделяется полосой белого цвета. Если вы снова запустите программу, она продолжит работу с прерванного места. Чтобы начать сначала, уберите полосу с экрана клавишами Ctrl-F2.

Группа операторов, выполняющихся многократно, называется телом цикла. У нас это все операторы, начиная с Write ('Это ') и кончая GOTO m1.

Пример программы:

LABEL 8;

VAR a,k : Integer;

BEGIN

k:=6;

a:=100;

goto 8;

a:=a+k;

k:=2*k;

WriteLn(a);

8: a:=a+1;

k:=k+10;

WriteLn(k,' ' ,a);

END.

Эта программа напечатает 16 101. Операторы выполняются в такой последовательности:

k:=6;

a:=100;

goto 8;

a:=a+1;

k:=k+10;

WriteLn(k,' ' ,a);

А операторы a:=a+k; k:=2*k; WriteLn(a) выполнены не будут вообще, несмотря на то, что написаны.

Задание 30: Определить без компьютера, что будет печатать программа:

LABEL m1,met5;

VAR n,k : Integer;

BEGIN

n:=10;

k:=0;

WriteLn('Считаем зайцев' );

met5: Write(n);

n:=n+k;

goto m1;

n:=n+1;

m1: Write(' зайцев ');

ReadLn;

k:=k+1;

goto met5;

WriteLn('Посчитали зайцев')

END.

А теперь, уважаемый читатель, нам с вами пришла пора снова отвлечься от программирования и расширить свои знания о работе на компьютере. Сейчас вам необходимо проделать то, что сказано в части IV в параграфе «Работа с несколькими окнами» и пункте «Работа с окнами пользователя и отладчика» параграфа «Исправление ошибок. Отладка программы».

Задания 31-33:

Написать программы для выполнения следующих заданий:

Бесконечно печатать букву А: ААААААААААА.....

Бесконечно печатать 1000 999 998 997 996 ......

Бесконечно печатать 100 50 25 12.5.... с 8 десятичными знаками.

Примечание: Во всех программах используйте ReadLn для создания паузы на каждом цикле. Чтобы программа шла все-таки довольно быстро, нажмите клавишу ввода и не отпускайте.

2.3.2 Выход из цикла с помощью if

Интересно рассмотреть применение оператора goto внутри операторов if или case.

Задача: При помощи цикла напечатать на экране:

Начало счета 3 5 7 9 Конец счета

Вот три варианта программы. Первый - самый простой, а второй и третий нам понадобятся в дальнейшем.

1 ВАРИАНТ	2 ВАРИАНТ
LABEL m; VAR f : Integer; BEGIN Write('Начало счета '); f:=3; m: Write(f,' '); f:=f+2; if f<=9 then goto m; Write(' Конец счета') END.	LABEL m1,m2; VAR f : Integer; BEGIN Write('Начало счета '); f:=3; m1: Write(f,' '); f:=f+2; if f>9 then goto m2 else goto m1; m2: Write(' Конец счета') END.

Вот в каком порядке выполняются операторы программы первого варианта:

Write('Начало счета ') f:=3 Write(f,' ') {печатается 3} f:=f+2 {f становится равным 5} if f<=9 goto m Write(f,' ') {печ. 5} f:=f+2 {f = 7} if f<=9 goto m Write(f,' ') {печ. 7} f:=f+2 {f = 9} if f<=9 goto m Write(f,' ') {печ. 9} f:=f+2 {f = 11} if f<=9 Write(' Конец счета')

Здесь оператор goto выполняется три раза. На четвертый раз условие f<=9 оказывается ложным и поэтому выполняется не goto, а следующий за if оператор Write(' Конец счета'), то есть программа выходит из цикла и завершает свою работу.

3 ВАРИАНТ
LABEL m1,m2,m3; VAR f : Integer; BEGIN Write('Начало счета '); f:=3; m1: if f<=9 then goto m3 else goto m2; m3: Write(f,' '); f:=f+2; goto m1; m2: Write(' Конец счета') END.

Задания 34-36:

Напечатать 1 2 3 4 . . . 99 100 99 . . . 3 2 1.

"Таблицы Брадиса"- вычислить и напечатать с 6 десятичными знаками квадраты чисел 0.000 0.001 0.002 0.003 . . . 0.999 1.000.

Для х=2700, 900, 300, 100 . . . и т.д. вычислять и печатать y=x/4 + 20 и z=2y+0.23 до тех пор, пока yz не станет меньше 1/х.

Совет: Теперь, когда вы владеете отладочным режимом, смело применяйте его всякий раз, когда ваша программа не хочет делать то, что нужно. Зачем ломать голову над непослушной программой? - Берегите серое вещество, жмите F7!

2.3.3 Оператор цикла repeat

Циклы настолько широко применяются в программах, что у программистов давным-давно появилась потребность написать специальный оператор цикла, не использующий оператор goto, так как последний неудобен хотя бы тем, что у программистов, пишущих большие программы, много времени и внимания уходит на поиск взглядом меток в тексте программы.

В Паскале - три оператора цикла: repeat, while и for. Первым изучим оператор repeat.

Конструкция repeat . . . . . until a+2>3*b читается "ри'пит.....ан'тил...", а переводится "повторяй......до тех пор, пока a+2 не станет больше 3*b".

Составим с использованием оператора repeat программу решения задачи о печати чисел 3 5 7 9 из предыдущего параграфа. Для того, чтобы точно определить работу оператора repeat, приведем ее параллельно со вторым вариантом программы решения этой задачи из того же параграфа:

2 ВАРИАНТ	ВАРИАНТ С REPEAT
LABEL m1,m2; VAR f : Integer; BEGIN Write('Начало счета '); f:=3; m1: Write(f,' '); f:=f+2; if f>9 then goto m2 else goto m1; m2: Write(' Конец счета') END.	VAR f : Integer; BEGIN Write('Начало счета '); f:=3; repeat Write(f,' '); f:=f+2; until f>9; Write(' Конец счета') END.

Порядок работы обеих программ совершенно одинаков, так что можно считать слово repeat заменой метки m1, а конструкцию until f>9 считать заменой оператора if f>9 then goto m2 else goto m1.

Синтаксис оператора repeat:

Repeat оператор ; оператор ;. . . ; оператор until условие

Вкратце работу оператора repeat можно описать так: Повторяй выполнение операторов, стоящих между словами repeat и until, до тех пор, пока не станет истинным условие.

Более подробно работа оператора repeat описывается так:

Сначала компьютер по очереди выполняет операторы, стоящие после слова repeat, пока не дойдет до слова until, после чего проверяет истинность условия, стоящего после until. Если условие ложно, то компьютер снова по очереди выполняет эти операторы и снова проверяет истинность условия и т.д. Если условие оказывается истинным, то работа оператора repeat прекращается и компьютер переходит к выполнению следующего по порядку оператора.

Задача: Компьютер предлагает человеку ввести слово, после чего распечатывает это слово, снабдив его восклицательным знаком. Затем снова предлагает ввести слово и так до тех пор, пока человек не введет слово "Хватит". Распечатав его с восклицательным знаком, компьютер отвечает "Хватит так хватит" и заканчивает работу.

Придумаем строковую переменную, в которую человек будет с клавиатуры вводить слово. Назовем ее Slovo.

VAR Slovo : String;

BEGIN

repeat

WriteLn('Введите слово');

ReadLn(Slovo);

WriteLn(Slovo, '!')

until Slovo='Хватит';

WriteLn('Хватит так хватит')

END.

Задание 37: Усложним эту задачу. Пусть компьютер перед распечаткой каждого слова ставит его порядковый номер.

Задание 38-39: Выполнить с применением оператора repeat последние два задания из предыдущего параграфа.

Задание 40: Если камень бросить горизонтально со 100-метровой башни со скоростью v=20м/с, то его расстояние от башни по горизонтали (s) будет выражаться формулой s=vt, где t - время полета камня в секундах. Высота над землей h будет выражаться формулой h=100 - 9.81t2/2. Вычислять и печатать t, s и h для t=0, 0.2, 0.4, 0.6 и так далее до тех пор, пока камень не упадет на землю.

2.3.4 Оператор цикла while

Синтаксис оператора while:

WHILE условие DO оператор

Слово while читается "вайл", слово do - "ду", вся конструкция переводится так - Пока условие истинно, делай оператор. Например, while a>b do b:=b+1.

Работает оператор while так:

Сначала компьютер проверяет истинность условия, стоящего после слова while. Если условие истинно, то выполняется оператор, стоящий после do. Затем снова проверяется истинность условия и в случае истинности снова выполняется этот оператор. И т.д. Если условие ложно, то оператор while прекращает свою работу и компьютер переходит к выполнению следующего оператора.

Оператор, стоящий после while, вполне может быть составным, поэтому тело цикла у оператора while, так же как и у оператора repeat, может состоять из многих операторов.

Решим при помощи while ту же задачу о печати чисел 3 5 7 9, что в предыдущем параграфе решили с помощью repeat. Для того, чтобы точно определить работу оператора while, приведем программу ее решения параллельно с третьим вариантом программы из 6.2:

3 ВАРИАНТ	ВАРИАНТ С WHILE
LABEL m1,m2,m3; VAR f : Integer; BEGIN Write('Начало счета '); f:=3; m1: if f<=9 then goto m3 else goto m2; m3: Write(f,' '); f:=f+2; goto m1; m2: Write(' Конец счета') END.	VAR f : Integer; BEGIN Write('Начало счета '); f:=3; while f<=9 do begin Write(f,' '); f:=f+2; end; Write(' Конец счета') END.

Как видите, здесь после do стоит составной оператор begin Write(f,' '); f:=f+2; end. Последовательность исполнения операторов и проверки условий в обеих программах совершенно аналогичны.

Типичная ошибка начинающих - небрежное обращение со знаками сравнения. Многие не видят большой разницы в том, как записать - while f<=9 или while f<9 , а затем, «недополучив» результат, удивляются, почему. И здесь лучшим средством для понимания является отладочный режим. Попробуйте ошибочный вариант последней программы (с while f<9) выполнить в пошаговом режиме с использованием окон пользователя и отладчика. Для этого введите в окно отладчика две вещи: переменную f и выражение f<9 (оно может иметь только два значения: true - истина и false - ложь, другими словами - «условие выполнено» и «условие не выполнено»).

Задание 41: Вычислять с использованием while квадратные корни из чисел 900, 893, 886, 879 и т.д. до тех пор, пока это можно делать.

2.3.5 Отличия операторов repeat и while

Отличий три:

Компьютер выходит из цикла оператора repeat тогда, когда условие истинно, а из цикла оператора while - когда условие ложно.

while может ни разу не выполнить оператор, стоящий после do. repeat же хотя бы раз операторы, стоящие между repeat и until, выполнит.

Так, фрагмент k:=8; repeat k:=1 until 3>2; WriteLn(k) напечатает 1.

А фрагмент k:=8; while 2>3 do k:=1; WriteLn(k) напечатает 8.

При компиляции оператор while дает несколько более эффективную программу, чем оператор repeat.

Часто эти отличия для начинающих малосущественны, поэтому выбирайте оператор по вкусу. Мне, например, надоели паскалевские begin и end, поэтому я охотнее пользуюсь оператором repeat.

2.3.6 Оператор цикла for

Выполняя программу печати чисел 3 5 7 9, оператор repeat выполнил цикл 4 раза. То же самое сделал и оператор while. Однако, обычно, когда мы пишем операторы repeat и while, нам совсем неважно знать, сколько раз они выполнят цикл. Тем не менее, существует много задач, для решения которых цикл нужно выполнить именно определенное количество раз. В этом случае удобно использовать оператор цикла for.

Задача: 200 раз напечатать слово ФУТБОЛ.

Попробуем сначала решить задачу при помощи оператора goto. Начнем с такого фрагмента:

metka: WriteLn('ФУТБОЛ')

goto metka

Но здесь цикл будет повторяться бесконечно, а нам нужно только 200 раз. Мы уже видели, что для выхода из цикла оператор goto нужно включить в состав оператора if. Кроме этого нужна переменная, меняющая свое значение от одного выполнения цикла к следующему. Придумаем этой величине какое-нибудь имя, скажем i. Проще всего задачу решает такой фрагмент:

i:=1;

metka: WriteLn('ФУТБОЛ');

i:=i+1; {увеличение i на 1}

if i<=200 then goto metka

END.

Здесь i вначале равно 1, но к каждому следующему выполнению цикла оно увеличивается на 1. В первый раз выполняя оператор if, компьютер проверяет условие 2<=200 и найдя его истинным, выполняет оператор goto metka. Во второй раз проверяется условие 3<=200 и т.д. В 199-й раз компьютер проверяет условие 200<=200 и найдя его истинным, выполняет оператор goto metka. В 200-й раз компьютер проверяет условие 201<=200 и найдя его ложным, выходит из цикла.

В нашем фрагменте "полезную" работу выполняет только одна строка из четырех - WriteLn('ФУТБОЛ'). Остальные три строки заняты тем, что обеспечивают выполнение "полезной" строки ровно 200 раз. Нам пришлось организовать специальную переменную, значение которой в каждый момент выполнения программы говорит о том, в какой раз выполняется цикл. Переменная с таким свойством называется счетчиком циклов.

А теперь запишем программу полностью, правда, несколько усложнив ее, так чтобы логика ее выполнения полностью соответствовала логике выполнения программы с оператором for, которую я привожу параллельно и поясняю немедленно.

LABEL m1,m2; VAR i : Integer; BEGIN i:=1; m1: if i>200 then goto m2; WriteLn('ФУТБОЛ'); i:=i+1; goto m1; m2: END.	VAR i : Integer; BEGIN for i:=1 to 200 do WriteLn('ФУТБОЛ') END.

Слово for читается "фо", переводится "для". Слово to читается "ту", переводится "до". Слово do читается "ду", переводится "делай". Конструкция for i:=1 to 200 do по-русски читается так: Для i, изменяющегося от 1 до 200, делай оператор, стоящий после слова do. Смысл повторения здесь такой же, как и в операторе while. Оператор, стоящий после do, тоже, конечно, может быть составным.

Синтаксис оператора for:

FOR имя := выражение1 TO выражение2 DO оператор

Пример записи: for j:=a+b to 2*s do k:=k+1.

Пояснения к синтаксической схеме:

имя - это имя произвольной переменной порядкового типа (см. 5.7 и 12.8), в частности целочисленной, называемой переменной цикла,

выражение1 и выражение2 - произвольные выражения порядкового типа, в частности - целого.

Работа оператора for:

Прежде всего вычисляется выражение1, и переменной цикла (пусть это будет i) присваивается его значение. Затем вычисляется выражение2 и сравнивается с i. Если i > выражения2, то оператор for завершает свою работу, так ничего и не сделав. В противном случае выполняется оператор, стоящий после do. После выполнения этого оператора значение i увеличивается на 1 и снова сравнивается с выражением2. Если i > выражения2, то оператор for завершает свою работу, иначе снова выполняется оператор, стоящий после do, снова i увеличивается на 1 и т.д.

В нашем примере переменная i кроме того, что обеспечивает нам выход из цикла, никакой "полезной" работы не выполняет. Усложним же немного задачу. Пусть компьютер печатает такую информацию:

10 ФУТБОЛ 11 ФУТБОЛ 12 ФУТБОЛ . . . . . 200 ФУТБОЛ

Вот программа:

VAR i : Integer;

BEGIN

for i:=10 to 200 do

begin Write(i);

Write(' ФУТБОЛ ')

end

END.

Здесь после do стоит уже составной оператор.

Можно ли удобно использовать оператор for для печати такой информации?:

100 ФУТБОЛ 99 ФУТБОЛ 98 ФУТБОЛ . . . . . 40 ФУТБОЛ

Вполне, так как оператор for позволяет не только увеличивать, но и уменьшать переменную цикла. Однако, для этого нельзя писать for i:=100 to 40, а нужно писать for i:=100 downto 40. Читается downto - "'даунту", переводится буквально "вниз до". Соответственно, для выхода из цикла должно быть истинным не условие i > выражения2, а условие i < выражения2.

Вот объединенный синтаксис оператора for:

FOR имя := выражение1 TO DOWNTO выражение2 DO оператор

Вертикальная черта между двумя элементами конструкции «TO и DOWNTO» говорит о том, что в конструкции должен присутствовать один из этих элементов.

Задание 42: Напечатать с помощью оператора for:

Прямой счет: -5 -4 -3 -2 -1 0 1 2 3 4 5 Обратный счет: 5 4 3 2 1 0 -1 -2 -3 -4 -5 Конец счета

2.4 Типичные маленькие программы

Каждому программисту известны такие понятия, как счетчик, сумматор, вложенные циклы и подобные понятия, составляющие элементарную технику программирования. Без них не обходится ни одна реальная программа. В этой главе я не буду вводить новых операторов, а покажу, как программировать типичные задачи, в том числе и те, что используют упомянутые понятия.

2.4.1 Вычислительная циклическая программа

Задача: Во дворце 40 залов. Известны длина, ширина и высота каждого зала. Вычислить площадь пола и объем каждого зала.

Сначала напишем фрагмент для одного зала:

ReadLn (dlina, shirina, visota);

S:=dlina*shirina; {Площадь пола}

V:=S*visota; {Объем}

WriteLn(S,' `,V)

Для решения задачи этот фрагмент нужно выполнить 40 раз, для чего вполне естественно использовать оператор for:

VAR i, dlina, shirina, visota, S, V: Integer;

BEGIN

for i:=1 to 40 do begin

ReadLn (dlina, shirina, visota);

S:=dlina*shirina;

V:=S*visota;

WriteLn(S,' `,V)

end {for}

END.

Обратите внимание, что здесь мы несколько модифицировали описанный нами в 5.4 ступенчатый стиль, а именно записали end не под соответствующим ему begin, а под соответствующим ему for. Эта практика также распространена, так как экономит место по вертикали. Мне она нравится больше, поэтому я буду ее придерживаться. Чтобы не спутаться, откуда взялся end, пишем рядом комментарий {for}.

Теперь создадим более дружественный интерфейс, для чего, кроме всего прочего, дадим возможность пользователю самому задавать число залов во дворце:

VAR i, dlina, shirina, visota, N, S, V : Integer;

BEGIN

WriteLn('Введите число залов`);

ReadLn (N); {N - число залов}

for i:=1 to N do begin

WriteLn('Введите длину,ширину и высоту зала`);

ReadLn (dlina, shirina, visota);

S:=dlina*shirina;

V:=S*visota;

WriteLn(`Площадь пола=',S,' Объем зала=`,V)

End

END.

Здесь курсивом я обозначил новые по сравнению с предыдущей программой элементы.

Пусть во дворце три зала размерами 20*15*4, 30*20*5 и 10*5*3. В этом случае мы вводим N=3 и оператор for выполняет цикл три раза. На каждом выполнении цикла компьютер останавливается на операторе ReadLn (dlina, shirina, visota), мы вводим числа и получаем результаты:

Площадь пола=300 Объем зала=1200

Площадь пола=600 Объем зала=3000

Площадь пола=50 Объем зала=150

Задание 43: Даны стороны N кубиков. Вычислить объем каждого.

2.4.2 Роль ошибок

Из 2.2 мы знаем, что по ошибочной программе компьютер выдает ошибочные результаты. Например, если в нашей программе мы вместо V:=S*visota напишем V:=S+visota, то результаты будут такими:

Площадь пола=300 Объем зала=304

Площадь пола=600 Объем зала=605

Площадь пола=50 Объем зала=53

Если случайно вместо for i:=1 to N написать for i:=2 to N то результаты будут такими:

Площадь пола=300 Объем зала=1200

Площадь пола=600 Объем зала=3000

На этом программа закончит работу и не спросит размеров третьего зала. Вам не кажется странным, что она посчитала 1 и 2 залы, а не 2 и 3? Если кажется, то учтите, что пользователь ничего не знает об ошибке в программе, а компьютер не говорит ему, размеры какого по счету зала ему нужно вводить.

Задания 44-45:

Определите без компьютера, что будет, если

строку for i:=1 to N do begin поместить под строкой ReadLn (dlina, shirina, visota)

поменять местами строки WriteLn(`Площадь пола=',S,' Объем зала=`,V) и end

Если задания не получаются, введите программы в компьютер и используйте отладочный режим.

2.4.3 Счетчики

Задача 1: В компьютер с клавиатуры вводятся числа. Компьютер после ввода каждого числа должен печатать, сколько среди них уже введено положительных.

Фрагмент, решающий задачу:

c:=0; {Обнуляем счетчик}

m: ReadLn(a); {Вводим очередное число}

if a>0 then c:=c+1;

WriteLn('Из них положительных - ' ,c);

goto m

Пояснения: В 6.6 мы придумали переменную i, которую назвали счетчиком циклов. Здесь мы тоже придумали переменную c. Она у нас выполняет роль счетчика положительных чисел. Сердце счетчика - оператор c:=c+1. Именно он в нужный момент увеличивает счетчик на 1. Но и без if a>0 then тоже никак нельзя. Если бы его не было, то c подсчитывал бы все числа без разбору, то есть был бы обыкновенным счетчиком циклов. В нашем же фрагменте увеличение с на 1 выполняется не всегда, а лишь при положительном а.

Пусть мы вводим числа 8, -2, 10 . . . В этом случае порядок выполнения операторов будет такой: